* mz11_isced_gml.sps .
* IBM SPSS Statistics 22 for Windows .
* Im Kommando '
' das lokale Arbeitsverzeichnis eintragen .
cd ''.
******************************************************************************.
* GESIS - Leibniz-Institut fuer Sozialwissenschaften .
* German Microdata Lab (GML) .
* Postfach 12 21 55 .
* 68072 Mannheim .
* Tel.: 0621/1246-265 Fax: 0621/1246-100 .
* E-Mail: gml@gesis.org .
* Christine Krings, Andreas Herwig .
* Version: 27.05.2014 .
******************************************************************************.
* ****************************************************************************.
* SPSS-Syntax zur Umsetzung der Bildungsklassifikation ISCED-1997.
* ISCED-Version des German Microdata Lab, GESIS.
* Bei Nutzung dieser Routine bitte wie folgt zitieren:
* (hier wird auch die Skalenkonstruktion beschrieben).
* Schroedter, J. H.; Lechert, Y.; Luettinger, P. (2006): Die Umsetzung der
* Bildungsskala ISCED-1997 fuer die Volkszaehlung 1970, die Mikrozensus-
* Zusatzerhebung 1971 und die Mikrozensen 1976-2004.
* ZUMA-Methodenbericht 2006/08. URL: http://www.gesis.org/fileadmin/upload/
* forschung/publikationen/gesis_reihen/gesis_methodenberichte/2006/
* 06_08_Schroedter.pdf .
* Programm: http://www.gesis.org/missy/fileadmin/missy/klassifikationen/
ISCED/ISCED_SPSS/mz11_isced_GML.sps
* Literaturhinweise, Quellen:
* United Nations Educational, Scientific and Cultural Organization 1997:
* International Standard Classification of Education ISCED 1997.
* http://www.uis.unesco.org/Library/Documents/isced97-en.pdf.
* OECD 1999: Classifying Educational Programmes. Manual for ISCED-97.
* Implementation in OECD Countries. 1999 Edition.
* http://www.oecd.org/education/skills-beyond-school/1962350.pdf .
* Datenbasis: Mikrozensus 2011, Scientific Use File.
* Datenbeschreibung:
* http://www.gesis.org/missy/auswahl-datensatz/mikrozensus-2011/ .
******************************************************************************.
* MZ 2011 .
******************************************************************************.
* Fuer lokalen Dateinamen eintragen; ggf. mit Variablenauswahl .
get file = "".
* Definition fehlender Werte aufheben - werden unten wieder zugewiesen .
missing values EF287 EF288 EF289 EF290 EF309 EF310k EF311 EF312k ().
******************************************************************************.
* Bildung der Variable "Allgemeinbildender Schulabschluss".
* Schulbesuch: Klasse 5-10 zu Haupt-/Volksschule .
* Klasse 11-13 zu Fachhochschulreife/Abitur .
* In den Mikrozensen bis 2004 gab es zur Frage "Allgemeiner Schulabschluss
* vorhanden" die Antwortkategorie "Ohne Angabe" (siehe u.a. MZ2004: EF258=9),
* die zur Bildung der Variable as=2 "ohne Angabe ob allgemeinbildender
* Schulabschluss" benoetigt wurde. Zur besseren Verstaendlichkeit entfaellt
* diese Kategorie ab MZ2005 und wird statt dessen bei der Frage "Hoechster
* Allgemeiner Schulabschluss" erfragt (siehe u.a. MZ2006: EF310=9) und zur
* Kategorie as=3 "ohne Angabe zur Art des Schulabschlusses" zusammengefasst.
* Im Mikrozensus 2008 wird bei der Frage zum Besuch von Schule und Hochschule
* in den letzten 4 Wochen erstmals auch erfragt, ob die Schule wegen Ferien
* oder Uebergang in eine andere Schule/Ausbildung nicht besucht wurde
* (Variable EF287=2). Diese Angabe wird im Folgenden wie ein Schulbesuch
* (EF287=1) behandelt.
* Ab dem Mikrozensus 2010 werden bei der korrigierten Variablen zum hoechsten
* allg. Schulabschluss (ef310k) Personen mit Abschluss der Polytechnischen
* Oberschule der DDR nach Abschluss mit 8. oder 9. Klasse, die 1975 oder spaeter
* geboren wurden, nicht der Kategorie 2 "Polytechnische Oberschule, usw."
* zugeordnet, sondern der Kategorie 1 "Haupt-(Volks-)schulabschluss".
recode ef310k (-3, -5=0) (6=1) (1=4) (2, 3, 7=5) (4, 5=6) (9=3) into as.
if (ef309=8) as=1.
if (((ef287>=1 & ef287<=2) | ef288=1) & ef290=2) as=7.
if (((ef287>=1 & ef287<=2) | ef288=1) & ef290=3) as=8.
recode as (4, 7=4) (6, 8=6).
variable lab as "Allgemeinbildender Schulabschluss".
value lab as
0 "entf."
1 "kein SA"
3 "o.A. zur Art d. SA"
4 "HS/VS/Kl.5-10"
5 "RS/POS"
6 "FHR/ABI/Kl.11-13".
formats as (f2.0).
******************************************************************************.
* Bildung der Variable "Berufsbildender Abschluss".
* In den Mikrozensen bis 2004 gab es zur Frage "Beruflicher Ausbildungs-
* oder Hochschul-/Fachhochschulabschluss vorhanden?" die Antwortkategorie
* "Ohne Angabe" (siehe u.a. MZ2004: EF260=9), die zur Bildung der Variable
* ba=2 "ohne Angabe ob beruflicher Abschluss" benoetigt wurde. Zur besseren
* Verstaendlichkeit entfaellt diese Kategorie ab MZ2005 und wird statt dessen
* bei der Frage "Hoechster beruflicher Ausbildungs- oder Hochschul-/
* Fachhochschulabschluss" erfragt (siehe u.a. MZ2006: EF312=99) und zur
* Kategorie ba=3 "ohne Angabe zur Art des beruflichen Abschlusses"
* zusammengefasst.
* Ab dem Mikrozensus 2010 werden bei der korrigierten Variablen zum hoechsten
* berufl. Abschluss (ef312k) Personen mit Anlernausbildung, die 1953 oder
* frueher geboren wurden, nicht der Kategorie 1 "Anlernausbildung, usw."
* zugeordnet, sondern der Kategorie 3 "Abschluss einer Lehre, usw.".
recode ef312k (-3, -5=0)
(1, 2=4)
(3, 4, 5, 6=5)
(7, 8, 9, 10, 11, 12=6)
(13, 14=7)
(15=8)
(99=3) into ba.
if (ef311=8) ba=1.
val lab ba
0 "Entfaellt (Pers<15)"
1 "kein BA"
3 "o.A. zur Art d. BA"
4 "Anlernausb./Praktikum/BVJ"
5 "Lehrausb./Berufsfachschule/Vorber.mittl.Dienst"
6 "Meister/Technik./Fachschule/Verw.FH/Berufsak."
7 "FH/Hochschule"
8 "Promotion".
var lab ba "Beruflicher Abschluss".
formats ba (f2.0).
******************************************************************************.
* Bildung der Hilfsvariable "Gegenwaertiger Besuch berufliche Schule".
* Im Mikrozensus 2008 wurden die Fragen zum Schulbesuch (EF287-EF293)
* modifiziert. Insbesondere wurden die ehemals drei Fragen zur Art der
* besuchten allgemeinbildenden Schule, der beruflichen Schule und der (Fach-)
* Hochschule 2008 in eine Frage (Variable EF289; MZ 2007: Variablen EF289-
* EF291) zusammengefasst.
do if ((ef287>=1 & ef287<=2) | ef288=1) & (ef289>=10 & ef289<=28).
recode ef289 (16,17,18,19,20 =4) (10,12,13,14,15=5) (21,22,23,24,25=6) (26,27=7) (28=8) into ba2.
end if.
mis val ba2 (99).
val lab ba2
4 "Berufsschule/BGJ/BVJ"
5 "berufl. Schule verm. RS/FHR"
6 "Fachschule, Fach-/Berufsakademie/2-3j. SdG, Verw.FH"
7 "FH/Hochschule"
8 "Promotion".
var lab ba2 "Gegenwaertiger Besuch berufliche Schule".
formats ba2 (f2.0).
******************************************************************************.
* Modifikation der Variable "Berufsbildender Abschluss" .
* Wenn der angestrebte berufliche Abschluss hoeher ist als der gegenwaertige,
* ersetzt dieser den "eigentlichen" beruflichen Abschluss .
do if (ba2=4 & ba2>ba).
recode ba (1, 3=4).
end if.
do if (ba2=5 & ba2>ba).
recode ba (1, 3, 4=5).
end if.
do if (ba2=6 & ba2>ba).
recode ba (1, 3, 4, 5=6).
end if.
do if (ba2=7 & ba2>ba).
recode ba (1, 3, 4, 5, 6=7).
end if.
do if (ba2=8 & ba2>ba).
recode ba (1, 3, 4, 5, 6, 7=8).
end if.
* Kreuztabelle zur Zuordnung der ISCED-Stufen .
cro as by ba.
*****************************************************************************.
* Bildung der Variable "ISCED-1997 - GML" .
* Aufgrund der Streichung der Variablen 'Besuch eines Kindergartens,
einer Kindergrippe bzw. eines Kinderhorts' ab MZ2005, kann die
ISCED-Kategorie 0, die den Elementarbereich (Vorschulbereich)
abbildet, nicht mehr gebildet werden.
compute is=99.
if (as=1 & ba=1) is=1.
if ((ef287>=1 & ef287<=2 | ef288=1) & ef290=1) is=2.
if ((as=0 | as=1) & (ba=3 | ba=4)) |
((as=3 | as=4) & (ba=0 | ba=1 | ba=3 | ba=4)) is=3.
if (as=5 & (ba=1 | ba=3 | ba=4)) is=4.
if ((as=0 | as=1 | as=3 | as=4 | as=5) & ba=5) is=5.
if (as=6 & (ba=1 | ba=3 | ba=4)) is=6.
if (as=6 & ba=5) is=7.
if (ba=6) is=8.
if (ba=7) is=9.
if (ba=8) is=10.
var lab is "ISCED-1997 - GML".
val lab is
1 "1B"
2 "1A"
3 "2B"
4 "2A"
5 "3B"
6 "3A"
7 "4A"
8 "5B"
9 "5A"
10 "6"
99 "entf./nicht zuordenbar".
formats is (f2.0).
fre is.
******************************************************************************.
* OPTIONAL:
* Ausschluss der Personen, die gegenwaertig noch in der Ausbildung sind.
* temporary.
* select if (ef287>2).
* fre is.
* Ausschluss von Personen, die unter 15 Jahre alt sind.
* temporary.
* select if (ef44>=15).
* fre is.
******************************************************************************.
* Eingangs aufgehobene fehlende Werte wieder definieren.
missing values EF287 EF288 EF289 EF290 EF309 EF310k EF311 EF312k (-3, -5).
******************************************************************************.